dim fso
dim version
dim file
dim assembly
dim assemblies
dim content
dim stream

assemblies = array("NBear.Common", "NBear.Data", "NBear.Tools.EntityGen", "NBear.Net", "NBear.Test", "NBear.Web", "NBear.IoC", "NBear.Tools.Configurator", "NBear.Tools.EntityImpl", "NBear.IoC.Servers.ServiceMQServer", "NBear.IoC.Hosts.ServiceHost")

Set fso = CreateObject("Scripting.FileSystemObject")

'get version
set file = fso.OpenTextFile("version_prefix.txt", 1, true, 0)
version = file.ReadLine()
file.Close()

for each assembly in assemblies
    'remove file readonly attribute
    set file = fso.GetFile(assembly & "\Properties\AssemblyInfo.cs")
    file.Attributes =  file.Attributes or 1

    'get old content
    set stream =  CreateObject("ADODB.Stream")
    stream.Type = 2
    stream.Charset = "UTF-8"
    stream.Open() 
    stream.LoadFromFile(assembly & "\Properties\AssemblyInfo.cs") 
    content = stream.ReadText()
    stream.Close()   
    
    'update content
    content = left(content, instr(content, "[assembly: AssemblyVersion(""") - 1) &_
        "[assembly: AssemblyVersion(""" & version & ".*"")]" & Chr(13) & Chr(10) &_
        "[assembly: AssemblyFileVersion("""  & version & ".*"")]" & Chr(13) & Chr(10)
    
    'delete old file 
    file.Delete(true)
    
    'save back
    stream.Open()
    stream.WriteText(content) 
    stream.SaveToFile assembly & "\Properties\AssemblyInfo.cs", 2
    stream.Close() 
next